Hatena::Groupvbscript

enapi.Evernote

主要な Windows 標準コンポーネントの一覧 → http://vbscript.g.hatena.ne.jp/keyword/ProgID
VBScript 基礎文法最速マスター → http://vbscript.g.hatena.ne.jp/cx20/20100131/1264906231

enapi.Evernote

enapi.Evernote

概要

enapi.EvernoteEvernoteCOM コンポーネントを識別する ProgID です。

このコンポーネントを使うことで VBScript から Evernote を利用することが可能になります。

サンプル

' File Name : CreateTestNote.vbs
' Usage : CScript //Nologo CreateTestNote.vbs
Option Explicit

Call Main()

Sub Main()

    Dim en
    Set en = CreateObject("enapi.Evernote")

    Dim strUserName
    Dim strPassword
    Dim strReserved
    strUserName = "UserName" ' ユーザ名
    strPassword = "********" ' パスワード
    strReserved = vbNullString
    en.Login strUserName, strPassword, strReserved
    
    Dim strTitle
    Dim strBody
    strTitle = "Note Title"
    strBody = "Hello, <b>Evernote</b> World."
    Dim note
    Set note = CreateNote( en, strTitle, strBody )

    ShowNote( note )
End Sub

Function CreateNote( en, strTitle, strBody )
    ' 本文は「Evernote Markup Language (ENML)」にて記述する必要があります。
    Dim strContent
    strContent = "<?xml version=""1.0"" encoding=""UTF-8""?>"
    strContent = strContent & "<!DOCTYPE en-note SYSTEM ""http://xml.evernote.com/pub/enml2.dtd"">"
    strContent = strContent & "<en-note>"
    strContent = strContent & strBody
    strContent = strContent & "</en-note>"
    ' ノートをタイトルと本文をセットして作成
    Dim note
    Set note = en.CreateNote( strTitle, strContent )
    ' ノートのノートブックプロパティにノートブックを関連付け
    note.Notebook = en.DefaultNotebook
    Set CreateNote = note
End Function

Sub ShowNote( note )
    WScript.Echo "Title = [" & note.Title & "]"
    WScript.Echo "Content = [" & note.Content & "]"
End Sub
実行結果
Title = [Note Title]
Content = [<?xml version="1.0" encoding="UTF-8"?><!DOCTYPE en-note SYSTEM "http:
//xml.evernote.com/pub/enml2.dtd"><en-note>Hello, <b>Evernote</b> World.</en-not
e>]

参考情報