Hatena::Groupvbscript

MODI.Document

主要な Windows 標準コンポーネントの一覧 → http://vbscript.g.hatena.ne.jp/keyword/ProgID
VBScript 基礎文法最速マスター → http://vbscript.g.hatena.ne.jp/cx20/20100131/1264906231

MODI.Document

MODI.Document

概要

MODI.Document は、Microsoft Office Document Imaging(Office 2003/2007 に付属)のオブジェクトを表す ProgID です。

このオブジェクトを使用することで、任意の画像ファイルに対して OCR (文字認識)を行うことが可能です。


Office 2003/2007 をお持ちでない場合は、Microsoft ダウンロード センターから無償でダウンロードできる SharePoint Designer 2007 をダウンロードして、インストール時に MODI のみを指定することでコンポーネントを導入可能です。

サンプル

' File : ImageToText.vbs
' Usage : CScript //Nologo ImageToText.vbs
' Description : VBScript から MODI.Document を使用して OCR を実行するサンプル
Option Explicit

Call Main()

Sub Main()
    Dim strFileName
    strFileName = "sample.bmp"
    Dim strText
    strText = ConvertImageToText( strFileName )
    DebugPrint "OCR 結果 = [" & strText & "]"
End Sub

Function ConvertImageToText( strFileName )
    Dim strResult
    Dim doc
    Set doc = CreateObject("MODI.Document")
    doc.Create strFileName ' *.tif, *.bmp, *.jpg, *.gif が使用可能
    doc.OCR ' OCR 実行
    Dim image
    Set image = doc.Images(0)
    Dim layout
    Set layout = image.Layout
    strResult = layout.Text ' OCR 実行結果を取得
    doc.Close
    ConvertImageToText = strResult
End Function

Sub DebugPrint( strMessage )
    ' WSH で実行する場合
    WScript.Echo strMessage
    ' VBA で実行する場合
    ' Debug.Print strMessage
End Sub
実行結果
Hello こんにちは

参考情報